98 lines
5.6 KiB
Bash
98 lines
5.6 KiB
Bash
fpath+=( $ZDOTDIR/completions )
|
|
|
|
# Don't offer history completion; we have fzf, C-r, and
|
|
# zsh-history-substring-search for that.
|
|
ZSH_AUTOSUGGEST_STRATEGY=(completion)
|
|
ZSH_AUTOSUGGEST_BUFFER_MAX_SIZE=30
|
|
|
|
# Expand partial paths, e.g. cd f/b/z == cd foo/bar/baz (assuming no ambiguity)
|
|
zstyle ':completion:*:paths' path-completion yes
|
|
|
|
# Fix slow one-by-one character pasting when bracketed-paste-magic is on. See
|
|
# zsh-users/zsh-syntax-highlighting#295
|
|
zstyle ':bracketed-paste-magic' active-widgets '.self-*'
|
|
|
|
# Options
|
|
setopt COMPLETE_IN_WORD # Complete from both ends of a word.
|
|
setopt PATH_DIRS # Perform path search even on command names with slashes.
|
|
setopt AUTO_MENU # Show completion menu on a successive tab press.
|
|
setopt AUTO_LIST # Automatically list choices on ambiguous completion.
|
|
# setopt AUTO_PARAM_SLASH # If completed parameter is a directory, add a trailing slash.
|
|
# setopt AUTO_PARAM_KEYS
|
|
# setopt FLOW_CONTROL # Disable start/stop characters in shell editor.
|
|
unsetopt MENU_COMPLETE # Do not autoselect the first completion entry.
|
|
unsetopt COMPLETE_ALIASES # Completion for aliases
|
|
# unsetopt ALWAYS_TO_END # Move cursor to the end of a completed word.
|
|
unsetopt CASE_GLOB
|
|
|
|
# Fuzzy match mistyped completions.
|
|
zstyle ':completion:*' completer _complete _list _match _approximate
|
|
zstyle ':completion:*:match:*' original only
|
|
zstyle ':completion:*:approximate:*' max-errors 1 numeric
|
|
# Increase the number of errors based on the length of the typed word.
|
|
zstyle -e ':completion:*:approximate:*' max-errors 'reply=($((($#PREFIX+$#SUFFIX)/3))numeric)'
|
|
# Don't complete unavailable commands.
|
|
zstyle ':completion:*:functions' ignored-patterns '(_*|.*|pre(cmd|exec))'
|
|
# Group matches and describe.
|
|
zstyle ':completion:*:corrections' format '%B%F{green}%d (errors: %e)%f%b'
|
|
zstyle ':completion:*:messages' format '%B%F{yellow}%d%f%b'
|
|
zstyle ':completion:*:warnings' format '%B%F{red}No such %d%f%b'
|
|
zstyle ':completion:*:errors' format '%B%F{red}No such %d%f%b'
|
|
zstyle ':completion:*:descriptions' format $'%{\e[35;1m%}%d%{\e[0m%}'
|
|
zstyle ':completion:*:default' list-prompt '%S%M matches%s'
|
|
# Omit parent and current directories from completion results when they are
|
|
# already named in the input.
|
|
zstyle ':completion:*:*:cd:*' ignore-parents parent pwd
|
|
# Merge multiple, consecutive slashes in paths
|
|
zstyle ':completion:*' squeeze-slashes true
|
|
# Don't wrap around when navigating to either end of history
|
|
zstyle ':completion:*:history-words' stop yes
|
|
zstyle ':completion:*:history-words' remove-all-dups yes
|
|
zstyle ':completion:*:history-words' list false
|
|
zstyle ':completion:*:history-words' menu yes
|
|
# Exclude internal/fake envvars
|
|
zstyle ':completion::*:(-command-|export):*' fake-parameters ${${${_comps[(I)-value-*]#*,}%%,*}:#-*-}
|
|
# Sory array completion candidates
|
|
zstyle ':completion:*:*:-subscript-:*' tag-order indexes parameters
|
|
# Complete hostnames from ssh files too
|
|
zstyle -e ':completion:*:hosts' hosts 'reply=(
|
|
${=${=${=${${(f)"$(cat {/etc/ssh_,~/.ssh/known_}hosts(|2)(N) 2>/dev/null)"}%%[#| ]*}//\]:[0-9]*/ }//,/ }//\[/ }
|
|
${=${${${${(@M)${(f)"$(cat ~/.ssh/config 2>/dev/null)"}:#Host *}#Host }:#*\**}:#*\?*}}
|
|
)'
|
|
# Don't complete uninteresting users
|
|
zstyle ':completion:*:users' ignored-patterns \
|
|
adm amanda apache avahi beaglidx bin cacti canna clamav daemon \
|
|
dbus distcache dovecot fax ftp games gdm gkrellmd gopher \
|
|
hacluster haldaemon halt hsqldb ident junkbust ldap lp mail \
|
|
mailman mailnull mldonkey mysql nagios \
|
|
named netdump news nfsnobody nobody 'nixbld*' nscd ntp nut nx openvpn \
|
|
operator pcap postfix postgres privoxy pulse pvm quagga radvd \
|
|
rpc rpcuser rpm shutdown squid sshd sync 'systemd-*' uucp vcsa xfs '_*'
|
|
# ... unless we really want to.
|
|
zstyle '*' single-ignored show
|
|
# Ignore multiple entries.
|
|
zstyle ':completion:*:(rm|kill|diff):*' ignore-line other
|
|
zstyle ':completion:*:rm:*' file-patterns '*:all-files'
|
|
# PID completion for kill
|
|
zstyle ':completion:*:*:*:*:processes' command 'ps -u $LOGNAME -o pid,user,command -w'
|
|
zstyle ':completion:*:*:kill:*:processes' list-colors '=(#b) #([0-9]#) ([0-9a-z-]#)*=01;36=0=01'
|
|
zstyle ':completion:*:*:kill:*' menu yes select
|
|
zstyle ':completion:*:*:kill:*' force-list always
|
|
zstyle ':completion:*:*:kill:*' insert-ids single
|
|
# Man
|
|
zstyle ':completion:*:manuals' separate-sections true
|
|
zstyle ':completion:*:manuals.(^1*)' insert-sections true
|
|
# Media Players
|
|
zstyle ':completion:*:*:mpg123:*' file-patterns '*.(mp3|MP3):mp3\ files *(-/):directories'
|
|
zstyle ':completion:*:*:mpg321:*' file-patterns '*.(mp3|MP3):mp3\ files *(-/):directories'
|
|
zstyle ':completion:*:*:ogg123:*' file-patterns '*.(ogg|OGG|flac):ogg\ files *(-/):directories'
|
|
zstyle ':completion:*:*:mocp:*' file-patterns '*.(wav|WAV|mp3|MP3|ogg|OGG|flac):ogg\ files *(-/):directories'
|
|
# SSH/SCP/RSYNC
|
|
zstyle ':completion:*:(scp|rsync):*' tag-order 'hosts:-host:host hosts:-domain:domain hosts:-ipaddr:ip\ address *'
|
|
zstyle ':completion:*:(scp|rsync):*' group-order users files all-files hosts-domain hosts-host hosts-ipaddr
|
|
zstyle ':completion:*:ssh:*' tag-order 'hosts:-host:host hosts:-domain:domain hosts:-ipaddr:ip\ address *'
|
|
zstyle ':completion:*:ssh:*' group-order users hosts-domain hosts-host users hosts-ipaddr
|
|
zstyle ':completion:*:(ssh|scp|rsync):*:hosts-host' ignored-patterns '*(.|:)*' loopback ip6-loopback localhost ip6-localhost broadcasthost
|
|
zstyle ':completion:*:(ssh|scp|rsync):*:hosts-domain' ignored-patterns '<->.<->.<->.<->' '^[-[:alnum:]]##(.[-[:alnum:]]##)##' '*@*'
|
|
zstyle ':completion:*:(ssh|scp|rsync):*:hosts-ipaddr' ignored-patterns '^(<->.<->.<->.<->|(|::)([[:xdigit:].]##:(#c,2))##(|%*))' '127.0.0.<->' '255.255.255.255' '::1' 'fe80::*'
|